Función amortización lineal en Excel

A continuación describiremos el uso de la función AMORTIZ.LIN en Microsoft Excel.

Estas funciones devuelven la amortización de cada período contable. Además se proporciona para el sistema contable francés. Si se compra un bien durante el período contable, la regla de amortización prorrateada se aplica al cálculo de la amortización.

Sintaxis:

AMORTIZ.LIN(costo; fecha_compra; primer_período; costo_residual; período; tasa; [base])

La función tienen los siguientes argumentos:

• Costo:    Obligatorio. El costo o valor de compra del bien.
• Fecha_compra:    Obligatorio. La fecha de compra del bien.
• Primer_período:    Obligatorio. La fecha del final del primer período.
• Costo_residual:    Obligatorio. El valor residual o valor del bien al final del período de la amortización.
• Período:    Obligatorio. El período.
• Tasa:    Obligatorio. La tasa de amortización.
• Base:    Opcional. La base anual usada.

Base	Base para contar días
0 u omitido	360 días (Método NASD)
1	Real
3	365 al año
4	360 al año (Sistema europeo)

Caso Práctico:

Para nuestro ejemplo utilizaremos los siguientes datos

Para este caso utilizaremos la función AMORTIZ.LIN que corresponde a la amortización lineal. Además de los datos necesarios para la función, podemos calcular otros datos adicionales que nos podría servir:

Primero calcularemos Días base, que es la cantidad de días que cuenta el año del Primer periodo, según la Base seleccionada. Para este campo puedes utilizar la siguiente fórmula:

=SI(Base=3;
365;
SI(Base=1;
PrimerPeriodo-FECHA(AÑO(FechaCompra);1;0);
360
)
)

Otro dato que es conveniete calcular, es la Amortización diaría, ya que la amortización es lineal, entonces la Amortización diaria es constante. Así tenemos para este dato:

=(Costo*Tasa)/DiasBase

Otro datos que nos podría servir es saber cuantos años de Vida útil tiene el activo, para ello utilaremos la siguiente fórmula:

=1/Tasa

Ahora pasaremos a utilizar la función de amortización lineal para generar la tabla de la amortización, donde aplicaremos la funcion AMORTIZ.LIN.

Con los datos de la tabla anterior, procedemos a llenar la tabla de amortización.

Entonces para la columa AMORTIZ.LIN utilizaremos la siguiente fórmula:

=AMORTIZ.LIN(Costo;FechaCompra;PrimerPeriodo;CostoResidual;E2;Tasa;Base)

Para la columna Valor en libros, nos muestra la diferencia del valor del bien con el que inicia el perido y la amortización aplicada en el periodo. Así tenemos:

=Costo-F2 , para la primera fila.

=G2-F3 , para la sigiuente fila y así sucesivamente.

Para la columna Días Amortización, podemos utilizar el valor de AMORTIZ.LIN para el periodo y dividirlo con la Amortización diaria. Pero podemos también calcular este dato utilizando las Fecha compra, Primer periodo el valor de la Base usada, en el caso que no se utilice la fórmula de amortización de excel.

para la primera fila tenemos lo siguiente:

=SI(Base=0;
  DIAS360(FechaCompra;PrimerPeriodo;0);
  SI(Base=4;
   DIAS360(FechaCompra;PrimerPeriodo;1);
   DIAS(PrimerPeriodo;FechaCompra)
  )
 )

para la última fila tenemos:

=SI(Base=4;
  DIAS360(FECHA(D7;1;0);FECHA(D7;MES(FechaCompra);DIA(FechaCompra));1);
  SI(Base=0;
   DIAS360(FECHA(D7;1;0);FECHA(D7;MES(FechaCompra);DIA(FechaCompra));0);
   SI(Y(Base=1; RESIDUO(AÑO(FechaCompra);4)=0);
    FECHA(D7;MES(FechaCompra);DIA(FechaCompra)+1)-FECHA(D7;1;0);
    SI(RESIDUO(D7;4)=0;
     FECHA(D7;MES(FechaCompra);DIA(FechaCompra))-FECHA(D7;1;1);
     FECHA(D7;MES(FechaCompra);DIA(FechaCompra))-FECHA(D7;1;0)
    )
   )
  )
)

Vemos que la fórmula es más compleja debido a que toma a consideración los difrentes valores de Base anual usada, ya que los días del años varía según este dato, además se consideran los años bisiestos. Pero su objetivo es utilizar la diferencia de fechas para calcular los días cursados en el último periodo. Podemos observar que la suma de los días del primer periodo y del último dan como resultado 365, que es el valor de Días base, la cantidad de días que tiene el año selecionado según la Base anual usada.

Finalmente, si queremos hallar la amortización lineal sin utilizar la fórmula, nos queda multiplicar el valor de Amortización diaria, que es una constante, y los Díaz amortización de cada periodo. Sin embargo, si Costo residual es mayor a cero, tenemos que restarle a este producto.

=(H7*AmortizDiaria)-CostoResidual

TIPS:

Si queremos utilizar nombres en las celdas fijas, para que sea más amigable la escritura de fórmulas, podemos utilizar Nombres Definidos del menú Fórmulas

Además, si se desea escribir en la barra de fórmulas con multiples líneas, para el caso que el uso de la función SI sea extenso o anidada, utilizamos las teclas Alt + Enter, para escribir en la siguiente línea.