En la definición oficial de Microsoft se puede ver que la función SUMAPRODUCTO multiplica cada uno de los elementos de una o varias matrices y devuelve la suma de los productos.
Efectivamente, esto es lo que hace. Pero lo que no dice en esta página es que no sólo sirve para eso. Se trata de una de las funciones más versátiles con que cuenta Excel. Es capaz de manejar matrices de una forma muy elegante. Por eso, SUMAPRODUCTO es realmente útil a la hora de comparar dos o más rangos y calcular datos con varios criterios.
Definición y sintaxis de SUMAPRODUCTO
La función SUMAPRODUCTO es capaz de multiplicar los elementos de una o varias matrices (hasta 255), y devolver la suma de todos los productos.
La sintaxis no es muy complicada:
=SUMAPRODUCTO(rango_1;[rango_2;…])
- Rango_1: Obligatorio. Es el primer rango cuyos elementos quieres multiplicar y sumar.
- Rango_2, Rango_3, …: Opcional. Es el segundo, tercero, …n rango de celdas hasta un máximo de 256. En versiones de Excel anteriores a 2007, este número se reducía a 30 rangos.
- El número mínimo de rangos que se pueden incluir es uno, de forma que la función dará como resultado la suma de los elementos de la matriz.
Aunque SUMAPRODUCTO funciona con matrices, no es necesario introducirla pulsando Ctrl + Mayús + Intro (como la mayoría de fórmulas matriciales). Basta con pulsar Intro como con cualquier otra fórmula.
Algunas cosas que debes tener en cuenta:
- Todas las matrices introducidas como argumentos deben tener el mismo número de filas y de columnas. Si no es así, el resultado de la función será el error #¡VALOR!
- Si uno de los argumentos contiene valores no numéricos, éstos serán tratados como ceros.
- Si una de las matrices es un valor lógico, el resultado será VERDADERO o FALSO. En caso de tener que realizar algún calculo con este resultado, necesitarás convertir los valores a sus correspondientes numéricos (1 o 0). Puedes hacer esto utilizando el operador doble negación (–).
¿Cómo funciona SUMAPRODUCTO?
Para entender el funcionamiento de SUMAPRODUCTO tenemos el siguiente ejemplo:
En una hoja en la que en el rango A2:A5 tienes una serie de cantidades y en el rango B2:B5, los precios de los productos. El objetivo sería hallar el importe de la compra.
En el colegio te enseñaron que primero debes multiplicar cada cantidad por su precio y luego sumar esos importes parciales.
=SUMAPRODUCTO(A2:A5;B2:B5)
La fórmula toma el primer número de la primera matriz y la multiplica por el primer número de la segunda matriz. A continuación coge el segundo número de la primera matriz y lo multiplica por el segundo número de la segunda matriz…
Una vez que ha terminado de multiplicar, va sumando los resultados parciales para devolver el total.
Es decir, la función realiza las siguientes operaciones matemáticas:
= A2*B2 + A3*B3 + A4*B4 + A5*B5
Es una operación básica que podrías hacer incluso manualmente…, ¡pero imagina que en vez de cuatro registros tuvieses 200!
SUMAPRODUCTO con uno o varios criterios Y
En Excel siempre hay varias formas de hacer la misma tarea. En este ejemplo te muestro cómo utilizar SUMAPRODUCTO para sustituir la función CONTAR.SI.
Imagina que tiene una lista de productos en los que se muestra la previsión anual de ventas y lo que se ha vendido de cada uno. El objetivo de este ejemplo sería el de hallar el número de productos cuya venta real ha superado a la prevista.
=SUMAPRODUCTO(–(C2:C11>B2:B11))
En la columna C se encuentran los importes reales y en la B los previstos.
¿Y qué ocurre si tenemos más de una condición? Imagina que, además de contar los productos cuyo importe real es mayor que el previsto, quieres que solo cuente el número de «Producto 2». La solución estaría en agregar otro criterio de esta forma:
=SUMAPRODUCTO(–(C18:C27>B18:B27);–(A18:A27=»Producto 2″))
Sumas, cuentas y promedios con varias condiciones Y
Los más «antiguos» en el uso de Excel recordarán que hasta la introducción de las funciones SUMAR.SI, CONTAR.SI y PROMEDIO.SI en Excel 2007, la única forma de poder hacer operaciones de forma condicional era con SUMAPRODUCTO.
Aquí algunos ejemplos de cada una de las operaciones según la imagen de debajo:
Suponiendo que los criterios a utilizar son =Centro 2 y Categoría=Llave plana, las fórmulas que tendrías que utilizar serían las siguientes:
Para la cuenta:
=SUMAPRODUCTO(–(A2:A13=»Centro 2″);–(B2:B13=»Llave plana»))
Ó
=SUMAPRODUCTO((A2:A13=»Centro 2″)*(B2:B13=»Llave plana»))
Para la suma:
=SUMAPRODUCTO(–(A2:A13=»Centro 2″);–(B2:B13=»Llave plana»);C2:C13)
Ó
=SUMAPRODUCTO((A2:A13=»Centro 2″)*(B2:B13=»Llave plana»);C2:C13)
Para el promedio:
=SUMAPRODUCTO(–(A2:A13=»Centro 2″);–(B2:B13=»Llave plana»);C2:C13)/SUMAPRODUCTO(–(A2:A13=»Centro 2″);–(B2:B13=»Llave plana»))
Ó
=SUMAPRODUCTO((A2:A13=»Centro 2″)*(B2:B13=»Llave plana»);C2:C13)/SUMAPRODUCTO((A2:A13=»Centro 2″)*(B2:B13=»Llave plana»))
Combinar SUMAPRODUCTO con otras funciones
La función SUMAPRODUCTO se puede combinar con otras funciones de Excel. De esta forma, se pueden incluir varios pasos en una fórmula y no es necesario trabajar con celdas auxiliares para resultados intermedios. Por ejemplo, de la siguiente manera puedes redondear directamente hacia abajo el resultado de la función:
=REDONDEAR.MENOS(SUMAPRODUCTO(A2:A6;B2:B6);-1)
SUMAPRODUCTO es una de las funciones más potentes de Excel que te ofrece numerosas posibilidades para facilitar los cálculos complejos. Puedes utilizar la función por si sola, o en combinación con otras funciones.
Artículo que te recomendamos leer:
LAS FUNCIONES QUE TE AYUDARÁN A SUMAR EN EXCEL
¿Qué te pareció nuestra blog? Coméntanos.
